//Flies by and aims a barrage of small bullets at the player

script_enemy_main{

let GRenemy=("\script\Images\Enemies\Fairy2-12.png");
let SEshots3=("script\SoundEffects\shots3.wav");
let SEdeath=("script\SoundEffects\enemydeath1.wav");
let miny=GetClipMinY; let maxy=GetClipMaxY; let minx=GetClipMinX; let maxx=GetClipMaxX;
let cx=GetCenterX; let cy=GetCenterY;
let startx=GetX; let starty=GetY;
let frame=0; let time=0; let animation=0;
let ani=4;
let scale=0.5;
let shots=0;
let shotcolor=0; let shotspeed=0;
let oldX=0; let oldY=0;
let invincible=125;

if(startx<cx){
SetAngle(90);
SetSpeed(6);
}
if(startx>cx){
SetAngle(90);
SetSpeed(6);
}

@Initialize{
	LoadGraphic("\script\Images\Enemies\Fairy2-12.png");
	LoadSE("script\SoundEffects\shots3.wav");

	SetInvincibility(0);
	SetLife(2);
	SetDamageRate(10,3); 
	SetScore(1000);
	SetShotColor(255,255,255);
}

@MainLoop{

if(GetX<=minx-32 || GetX>=maxx+32 || GetY<=miny-32 || GetY>=maxy+32 && frame>=60){ VanishEnemy; }

if((GetX>minx && GetX<maxx) && (GetY>miny && GetY<maxy)){
SetCollisionA(GetX,GetY,32*scale);
SetCollisionB(GetX,GetY,32*scale);

if(GetCommonData("Difficulty")==1){
	if(time>=60 && shots<1){
		CreateShot02(GetX,GetY,3,GetAngleToPlayer,-0.1,1,36,0);
		PlaySE(SEshots3);
	shots+=1;
	}
} //Easy

//=================================================

if(GetCommonData("Difficulty")==2){
	if(time%20==0 && time>=60 && shots<3){
		CreateShot02(GetX,GetY,4,GetAngleToPlayer,-0.1,rand(2,2.5),36,0);
		PlaySE(SEshots3);
	shots+=1;
	}
} //Normal

//=================================================

if(GetCommonData("Difficulty")==3){
	if(time%15==0 && time>=60 && shots<7){
		CreateShot02(GetX,GetY,5.5,GetAngleToPlayer+rand(-3,3),-0.1,rand(2.5,3),36,0);
		PlaySE(SEshots3);
	shots+=1;
	}
} //Hard

//=================================================

if(GetCommonData("Difficulty")==4){
	if(time%10==0 && time>=60 && shots<10){
		CreateShot02(GetX,GetY,7,GetAngleToPlayer+rand(-5,5),-0.1,rand(3,4),36,0);
		PlaySE(SEshots3);
	shots+=1;
	}
} //Lunatic
} //Onscreen


if(startx<cx){
if(shots<4){ if(GetAngle>0){ SetAngle(GetAngle-2); } if(GetSpeed>1.5){ SetSpeed(GetSpeed-0.07); } }
if(shots>=4){ if(GetAngle>-90){ SetAngle(GetAngle-1); } SetSpeed(GetSpeed+0.05); }
}
if(startx>cx){
if(shots<4){ if(GetAngle<180){ SetAngle(GetAngle+2); } if(GetSpeed>1.5){ SetSpeed(GetSpeed-0.07); } }
if(shots>=4){ if(GetAngle<270){ SetAngle(GetAngle+1); } SetSpeed(GetSpeed+0.05); }
}


oldX=GetX;
oldY=GetY;
frame++;
time++;
animation++;
if(animation>=ani*6){ animation=0; }
if(GetTimeOfInvincibility<25 && invincible>0){ invincible=GetTimeOfInvincibility*5; }

}

@DrawLoop{
let side=0;
	SetTexture(GRenemy);
		if(oldX<GetX || oldX>GetX){ side=128; }
		if(animation>=ani*0 && animation<ani*1){ SetGraphicRect(1,side,256,128+side); }
		if(animation>=ani*1 && animation<ani*2){ SetGraphicRect(257,side,512,128+side); }
		if(animation>=ani*2 && animation<ani*3){ SetGraphicRect(513,side,768,128+side); }
		if(animation>=ani*3 && animation<ani*4){ SetGraphicRect(769,side,1024,128+side); }
		if(animation>=ani*4 && animation<ani*5){ SetGraphicRect(513,side,768,128+side); }
		if(animation>=ani*5 && animation<ani*6){ SetGraphicRect(257,side,512,128+side); }
	SetGraphicAngle(0,0,0);
	if(oldX<GetX){ SetGraphicAngle(180,0,0); }
	SetGraphicScale(scale,scale);
	SetColor(255-invincible,255-invincible,255);
	DrawGraphic(GetX,GetY);
}

@Finalize{
if(BeVanished==false){
PlaySE(SEdeath);
let random=rand_int(0,3);
	if(random==2){ CreateEnemyFromFile("script\Functions\itempower.txt",GetX+rand(-50,50),GetY+rand(-50,50),0,0,0); }
	if(random==3){ CreateEnemyFromFile("script\Functions\itempoint.txt",GetX+rand(-50,50),GetY+rand(-50,50),0,0,0); }
#include_function "script/Functions/PlayerTypeBonus.txt";
}
}

}